Home ›

Converting troff to HTML

Aug 13, 2008  By Phil Hughes
 in
Ok, more specifically, troff using the mm macros to HTML. This is another from my "rusty scripts" collection which was written for a specific task long ago. In this case, we were converting some internal documentation from troff using the mm macros into HTML.

troff is a very sophisticated system so doing this right would be a lot of work. But, writing something to get rid of 90% of the grunt work of conversion is pretty easy. Paul Dunne did one for the ms macro set which you can find here but mm is different.

As awk was (and maybe still is) my favorite choice for one-shot "fix the data" programs, it got called to duty to do the task. Here is what I decided was worth it. 

#!/usr/bin/awk -f
# troff -mm to HTML converter
# Phil Hughes--April 21, 1997
# Updates:
#
#
# This doesn't do everything and it is not intended to do everyting.
# It does what is easy.  In particular, headers and the title is
# not mucked with.  Also, center requests only center one line (I think).
#
# The goal here was to do the stuff that is a total pain to do by hand.
# This includes section numbering, font changes (which is still rather
# dumb) and lists.  The output of this program should be considered
# a good starting point for making good HTML.
#
# Here is what is currently recognized:
#   .H - deals with heading levels
#   .P - maps to <p> (as does a blank line)
#   .BL - maps to <ul>
#   .AL - maps to <ol>
#   .LE - maps to the end of the list of the type most recently started
#   .LI - <li>
#   .ds - tossed
#   .ce - centers next line
#   \fB, \f(HB, \fI, - changes to bold, bold or italic
#   \fP - goes back to previous font
#   \(em - --
#   .PF, .PH - tossed
#   \s - tossed
# That's all folks.
#

BEGIN   {
        BLANKS = "                                                "
        # beginning HTML crap
        print "<html>"
        print "<head>"
        print "<title> ============</title>"
        print "</head>"
        print "<body>"
        }

        {       # always convert these things
                # yes, there is a lot to add here
        gsub(/\\\(em/, "--")    # \em to --
        gsub(/.\\".*$/, "")     # trash comments
        gsub(/.PF.*$/, "")      # trash all sorts of headers & footers
        gsub(/.PH.*$/, "")      # trash all sorts of headers & footers
        gsub(/\\s[0-9+-][1-9]?/, "") # trash point size changes
        }

/^\.H / {       # heading
        head_level = $2

        head[head_level+1] = 0
        head[head_level+2] = 0
        head[head_level+3] = 0
        head[head_level+4] = 0
        head[head_level+5] = 0

        head[head_level]++
        $1 = ""
        $2 = ""
        gsub(/"/,"")

        printf "<h" head_level ">"
        for (x=1; x <= head_level; x++) {
                printf "%d.", head[x]
                }
        printf " "
        print $0 "</h" head_level ">"
        next
        }

/^ *$/  {       # paragraph
        "<p>"
        next
        }

/^\.P *$/       {       # paragraph
        print "<p>"
        next
        }

/^\.BL/ {       # bulleted list
        print "<ul>"
        list[++ll] = "</ul>"
        indent += 2
        next
        }

/^\.AL/ {       # alpha list
        print "<ol>"
        list[++ll] = "</ol>"
        indent += 2
        next
        }

/^\.LI/ {       # list item
        print substr(BLANKS, 1, indent) "<li>"
        next
        }


/^\.LE/ {       # list end
        print list[ll--]
        indent -= 2
        next
        }

/\.ds/  {       # trash them
        next
        }

/^\.ce/ {       # center next line(s)--only does one line for now
        print "<p align=\"center\">"
        next
        }

        {       # print whatever we have left

        # hard stuff like font changes where we need to remember
        split($0,tmp,"\\")
        for (x in tmp) {
                if (sub(/^fB/, "<b>", tmp[x]) == 1) {
                        new_sub = "</b>"
                        }
                if (sub(/^f\(HB/, "<b>", tmp[x]) == 1) {
                        new_sub = "</b>"
                        }
                if (sub(/^fI/, "<i>", tmp[x]) == 1) {
                        new_sub = "</i>"
                        }
                if (sub(/^fP/, new_sub, tmp[x]) == 1) {
                        new_sub = "#####"
                        }
                }

        for (x in tmp) {
                printf "%s", substr(BLANKS, 1, indent)
                printf "%s", tmp[x]
                }
        print ""
        }

END     {
        # ending HTML crap
        print "</body>"
        print "</html>"
        }

Most of this is pretty ordinary and brute force. Note that the indenting I add in the output is cosmetic to make it easier to see what is going on. The only "hard part" was dealing with the headings.

In troff with mm, headings are of the form section.subsection.subsubsection ... followed by text. For example, 3.5.1 This is a test would be a standard looking heading. I put this together by using an HTML heading tag of a corresponding level manually counting the number of sections at the current level. For those unfamiliar with awk, let's look at this piece of the code: 

        head[head_level]++
        $1 = ""
        $2 = ""
        gsub(/"/,"")

        printf ""
        for (x=1; x <= head_level; x++) {
                printf "%d.", head[x]
                }
        printf " "
        print $0 ""

The head array keeps track of the current section number at each level. After incrementing the section, the next two lines look a bit strange. In awk, $0 is the full input line and the pieces (parsed using the current field separator) get assigned to $1, $2 and so on. If you assign to htem, $0 gets updated so all this does is toss the first two fields from the input line—the troff .H tag and the level number.

The for look builds the section string and the final print statement prints the original input line minus the first two fields and appends the appropriate <\h to it.

Like with my shell script, this one a one-time fix that focused on the task at hand. Depending on what you had done in your troff code, there may be other tags worth converting.

______________________

Phil Hughes

Comments

Comment viewing options

Select your preferred way to display the comments and click "Save settings" to activate your changes.

yecch, doesn't work with tbl

cameron's picture
Submitted by cameron (not verified) on Tue, 07/28/2009 - 12:32.

I'm trying to get a printable version of the procps ("Linux ps") manpage.
groff -t -mandoc -Thtml sets the tables in images, and they're not even close to usable.
groff -t -mandoc -Tps sets the tables in Postscript but the paragraphs in table cells don't wrap, they go way off the page.
Best I can do so far is leave off the -t. The markup is easier to read than what groff does with it.

Ok, nice try. Are you aware

Anonymous's picture
Submitted by Anonymous (not verified) on Tue, 08/26/2008 - 16:26.

Ok, nice try.
Are you aware of groff which is able to generate HTML using -Thtml as output device
typical use is

$ groff -mwww -Thtml inputfile > out.html

Heinz

Webcast
More Resources
How to Build an Optimal Hadoop Cluster to Store and Maintain Unlimited Amounts of Data Using Microservers

Realizing the promise of Apache® Hadoop® requires the effective deployment of compute, memory, storage and networking to achieve optimal results. With its flexibility and multitude of options, it is easy to over or under provision the server infrastructure, resulting in poor performance and high TCO. Join us for an in depth, technical discussion with industry experts from leading Hadoop and server companies who will provide insights into the key considerations for designing and deploying an optimal Hadoop cluster.

Learn More

Sponsored by AMD

White Paper
More Resources
Red Hat White Paper: Using an Open Source Framework to Catch the Bad Guy

Built-in forensics, incident response, and security with Red Hat Enterprise Linux 6

Every security policy provides guidance and requirements for ensuring adequate protection of information and data, as well as high-level technical and administrative security requirements for a system in a given environment. Traditionally, providing security for a system focuses on the confidentiality of the information on it. However, protecting the data integrity and system and data availability is just as important. For example, when processing United States intelligence information, there are three attributes that require protection: confidentiality, integrity, and availability.

Learn more about catching the bad guy in this free white paper.

Learn More

Sponsored by DLT Solutions